Configurando o Projeto Gradle

Esta página descreve como adicionar o JxBrowser a um projeto Gradle.

Para adicionar o JxBrowser a um projeto Gradle, você deve incluir o plugin JxBrowser Gradle no seu arquivo de script de construção build.gradle(.kts) e configurar o projeto dependências lá.

Aplicando o plug-in

Para aplicar o plugin JxBrowser Gradle, use o bloco plugins do Gradle DSL:

plugins {
    id 'com.teamdev.jxbrowser' version '1.0.2'
}
plugins {
    id("com.teamdev.jxbrowser") version "1.0.2"
}

Configurando o plug-in

Uma vez aplicado, o plugin pode ser configurado através da extensão jxbrowser no arquivo build.gradle(.kts).

Versão

Defina a versão da biblioteca necessária utilizando a propriedade version:

jxbrowser {
    version '7.38.1'
}
jxbrowser {
    version = "7.38.1"
}

A propriedade version é obrigatória, a sua omissão resultará numa IllegalStateException.

Repositório

Você pode especificar a localização do repositório JxBrowser a ser utilizado, que pode ser a América do Norte ou a Europa:

jxbrowser {
    version '7.38.1'
    repository Repository.EUROPE
}
jxbrowser {
    version = "7.38.1"
    repository = Repository.EUROPE
}

Também pode especificar um repositório personalizado através do seu URL, como se mostra abaixo:

jxbrowser {
    version '7.38.1'
    repository 'https://my.custom.repository'
}
jxbrowser {
    version = "7.38.1"
    repository = "https://my.custom.repository"
}

Se a propriedade repository não for especificada, a localização é definida como América do Norte.

Pré-visualização de compilações

Utilize includePreviewBuilds() para adicionar ao projeto um repositório com builds de preview do JxBrowser:

jxbrowser {
    version '7.38.1'
    includePreviewBuilds()
}
jxbrowser {
    version = "7.38.1"
    includePreviewBuilds()
}

Dependências

Multiplataforma

Para adicionar a biblioteca JxBrowser que funciona no Windows, macOS e Linux, adicione o seguinte código:

dependencies {
    implementation jxbrowser.crossPlatform
}
dependencies {
    implementation(jxbrowser.crossPlatform)
}

Específico da plataforma

Se precisar de arquivos JAR do JxBrowser apenas para uma plataforma específica, pode utilizar a dependência adequada, conforme descrito abaixo.

Se a sua aplicação Java for executada apenas nas plataformas Windows e macOS e não necessitar da dependência do Linux, você pode incluir apenas as dependências do Windows e do macOS.

Windows 32-bit

dependencies {
    implementation jxbrowser.win32
}
dependencies {
    implementation(jxbrowser.win32)
}

Windows 64-bit

dependencies {
    implementation jxbrowser.win64
}
dependencies {
    implementation(jxbrowser.win64)
}

macOS 64-bit

dependencies {
    implementation jxbrowser.mac
}
dependencies {
    implementation(jxbrowser.mac)
}

macOS ARM de 64 bits

dependencies {
    implementation jxbrowser.macArm
}
dependencies {
    implementation(jxbrowser.macArm)
}

Linux 64-bit

dependencies {
    implementation jxbrowser.linux64
}
dependencies {
     implementation(jxbrowser.linux64)
}

Linux ARM de 64 bits

dependencies {
    implementation jxbrowser.linuxArm
}
dependencies {
    implementation(jxbrowser.linuxArm)
}

Plataforma atual

Para detectar a plataforma atual e adicionar os binários Chromium correspondentes, utilize a seguinte dependência:

dependencies {
    implementation jxbrowser.currentPlatform
}
dependencies {
    implementation(jxbrowser.currentPlatform)
}

Conjunto de ferramentas GUI

Swing

dependencies {
    implementation jxbrowser.swing
}
dependencies {
    implementation(jxbrowser.swing)
}

JavaFX

dependencies {
    implementation jxbrowser.javafx
}
dependencies {
    implementation(jxbrowser.javafx)
}

SWT

dependencies {
    implementation jxbrowser.swt
}
dependencies {
    implementation(jxbrowser.swt)
}

Resumo

Aqui está o código completo do build.gradle(.kts):

import com.teamdev.jxbrowser.gradle.Repository

plugins {
    id 'java'
    id 'com.teamdev.jxbrowser' version '1.0.2'
}

jxbrowser {
    // A versão do JxBrowser. Um campo obrigatório.
    version '7.38.1'

    // A localização do repositório do JxBrowser a utilizar. Pode ser na América do Norte ou na Europa.
    // Se não for especificado, a localização é definida para a América do Norte.
    repository Repository.NORTH_AMERICA

    // Alternativamente, ele pode apontar para um repositório personalizado através de sua URL, como a seguir:
    // repository "https://my.custom.repository"

    // Adiciona um repositório com compilações de pré-visualização do JxBrowser ao projeto.
    includePreviewBuilds()
}

dependencies {
    // Adiciona uma dependência ao núcleo da API do JxBrowser.
    implementation jxbrowser.core

    // Adiciona dependências aos binários do Chromium para todas as plataformas suportadas.
    implementation jxbrowser.crossPlatform

    // Adiciona uma dependência aos binários do Chromium específicos da plataforma.
    implementation jxbrowser.mac
    implementation jxbrowser.macArm
    implementation jxbrowser.win32
    implementation jxbrowser.win64
    implementation jxbrowser.linux64
    implementation jxbrowser.linuxArm

    // Detecta a plataforma atual e adiciona os binários Chromium correspondentes.
    implementation jxbrowser.currentPlatform

    // Adiciona dependências às integrações do kit de ferramentas UI.
    implementation jxbrowser.swt
    implementation jxbrowser.swing
    implementation jxbrowser.javafx
}
import com.teamdev.jxbrowser.gradle.Repository

plugins {
    java
    id("com.teamdev.jxbrowser") version "1.0.2"
}

jxbrowser {
    // A versão do JxBrowser. Um campo obrigatório.
    version = "7.38.1"

    // A localização do repositório do JxBrowser a utilizar. Pode ser América do Norte ou Europa.
    // Se não for especificado, a localização é definida para a América do Norte.
    repository = Repository.NORTH_AMERICA

    // Alternativamente, ele pode apontar para um repositório personalizado através de sua URL, como segue:
    // repository = "https://my.custom.repository"

    // Adiciona um repositório com compilações de pré-visualização do JxBrowser ao projeto.
    includePreviewBuilds()
}

dependencies {
    // Adiciona uma dependência ao núcleo da API do JxBrowser.
    implementation(jxbrowser.core)

    // Adiciona dependências aos binários do Chromium para todas as plataformas suportadas.
    implementation(jxbrowser.crossPlatform)

    // Adiciona uma dependência aos binários do Chromium específicos da plataforma.
    implementation(jxbrowser.mac)
    implementation(jxbrowser.macArm)
    implementation(jxbrowser.win32)
    implementation(jxbrowser.win64)
    implementation(jxbrowser.linux64)
    implementation(jxbrowser.linuxArm)
    
    // Detecta a plataforma atual e adiciona os binários Chromium correspondentes.
    implementation(jxbrowser.currentPlatform)
    
    // Adiciona dependências às integrações do kit de ferramentas UI.
    implementation(jxbrowser.swt)
    implementation(jxbrowser.swing)
    implementation(jxbrowser.javafx)
}
Go Top